4.2.3 - Drehzahl mit Temperatursteuerung

Teileliste

• Arduino IDE (Tutorial wurde mit 1.6 erstellt)

• Arduino Uno (oder ein anderes Modell)

• Breadboard

• Steckbrücken oder Kabel
  

• 12V Netzteil (das ist nur ein Beispiel! Bitte wählt ein ausreichend starkes Netzteil je nach benötigter Leistung)

• alternativ  12V Computer Netzteil

• 2x 10kΩ Widerstand

• 10kΩ NTC Widerstand

• alternativ Wakü Tempsensor (das sind auch nur 10kΩ NTC-Wiederstände in einem Metallgehäuse)
• 12V PC Lüfter (4 Pin PWM)

// Konstanten
const int fanPin = 9;                 // Pin für den Lüfter
const int tachoPin = 2;               // Pin des Tachosignals des Lüfters
const int ntc = A0;                   // Pin für den 10kO NTC Wiederstand
const int ntcNominal = 10000;         // Wiederstand des NTC bei Nominaltemperatur
const int tempNominal = 25;           // Temperatur bei der der NTC den angegebenen Wiederstand hat
const int bCoefficient = 3977;        // Beta Coefficient(B25 aus Datenblatt des NTC)
const int serienWiederstand = 10000;  // Wert des Wiederstands der mit dem NTC in Serie geschalten ist
const int abfrageZahl = 5;            // Je mehr abfragen, desto stabiler isr das Ergebnis, dauert aber länger

// Variablen
byte fanSpeed = 0;         // Variable für die Lüftergeschwindigkeit
int fanMin = 60;           // Kleinster PWM Wert für den Lüfter befor er abschält
int fanOut = 1;            // Variable zum pürfen ob der Lüfter aus war
int tMin = 20;             // Untere Grenze des Temperaturbereichs
int tMax = 60;             // Obere Grenze des Temperaturbereichs
int abfrage[abfrageZahl];  // Array Variable für das Mitteln der Temperatur
int abfrZeit = 1000;       // Zeitabstand für die Abfragen des Tachosignals
int rpm = 0;               // Variable für die gemittelte Drehzahl
float rps = 0;             // Variable mit Kommastelle für die Berechnung der Umdrehungen pro Sekunde
float umdrZeit = 0;        // Variable mit Kommastelle für die Zeit pro Umdrehung des Lüfters
float flankenZeit =0;      // Variable mit Kommastelle für die Zeit pro Puls des Lüfters
float durchschnitt = 0;    // Variable für das Mitteln der Temperatur
float temp;                // Variable für die Berechnung der temperatur nach Steinhart
unsigned long tachoMillis = abfrZeit;   // Variable zum speichern der Zeit


void setup()
{
  TCCR1B = TCCR1B & 0b11111000 | 0x01;   // Setzt Timer1 (Pin 9 und 10) auf 31300Hz
  Serial.begin(9600);             // Baudrate für die Ausgabe am Serial Monitor
  pinMode(fanPin, OUTPUT);        // Setzt den Pin des Lüfters als Ausgang
  pinMode(ntc, INPUT);            // Setzt den Pin des NTC Wiederstands als Eingang
  pinMode(tachoPin, INPUT);       // Setzt den Tacho Pin als Eingang
}


void loop()
{
  // Alle 1000ms die die Temperatur berechnen und die Drehzal auslesen
  if((millis() - tachoMillis) >= abfrZeit)
  { 
    temperaturberechnung();      // Startet die Temperaturerfassungsroutine
  
    // Lüftergeschwindigkeit über den Temperaturbereich verteilen
    // TMin->0% PWM | TMax->100% PWM
    fanSpeed = map(temp, tMin, tMax, 50, 255);    
  
    // Wenn die Temperatur unter tMin fällt, Lüfter auf niedrigste Stufe schalten
    if (temp < tMin)
    {
      fanSpeed = 0;
    }
    
    analogWrite(fanPin, fanSpeed);      // Den Lüfter mit dem PWM Wert ansteuern
    
    // Erfassen der Drehzahl
    flankenZeit = pulseIn(tachoPin, LOW);    // Abfrage der Zeit pro Puls in Mikrosekunden
    umdrZeit = ((flankenZeit * 4)/1000);     // Berechnung der Zeit pro Umdrehung in Millisekunden
    rps = (1000/umdrZeit);                   // Umrechnung auf Umdrehungen pro Sekunde
    rpm = (rps*6);                           // Schritt 1 zur Rundung auf 10er Schritte der Drehzahl
    rpm = (rpm*10);                          // Schritt 2 zur Rundung auf 10er Schritte der Drehzahl
    Serial.print("Drehzahl: ");              // Ausgabe der Drehzahl im Seriellen Monitor
    Serial.print(rpm);                       // Ausgabe der Drehzahl im Seriellen Monitor
    Serial.println(" RPM");                  // Ausgabe der Drehzahl im Seriellen Monitor
    tachoMillis = millis();      // Die TachoMillis werden aktualisiert um die nächsten 1000ms zählen zu können 
  }
} 


void temperaturberechnung()
{
  // Nimmt N Abfragen in einer Reihe, mit einem kurzen delay
  for (int i=0; i < abfrageZahl; i++)
  {
    abfrage[i] = analogRead(ntc);
    delay(10);
  }
  
  // Mittelt alle Abfragen
  durchschnitt = 0;
  for (int i=0; i < abfrageZahl; i++)
  {
    durchschnitt += abfrage[i];
  }
  durchschnitt /= abfrageZahl;
  
  // Umwandlung des Wertes in Wiederstand
  durchschnitt = 1023 / durchschnitt - 1;
  durchschnitt = serienWiederstand / durchschnitt;
  
  // Umrechnung aller Ergebnisse in die Temperatur mittels einer Steinhard Berechnung
  temp = durchschnitt / ntcNominal;     // (R/Ro)
  temp = log(temp);                     // ln(R/Ro)
  temp /= bCoefficient;                 // 1/B * ln(R/Ro)
  temp += 1.0 / (tempNominal + 273.15); // + (1/To)
  temp = 1.0 / temp;                    // Invertieren
  temp -= 273.15;                       // Umwandeln in °C
  
  // Ausgabe an den Seriellen Monitor
  Serial.print("Temperatur: ");
  Serial.print(temp);
  Serial.println("*C");
}